Have balanced growth test consider steady_state_model-block

Here is an example where an error in trend declaration isn't detected by the balanced growth test. It may come from the fact that labor enhancing productivity (G) is not a variable of the model, just a trend. The error should appear for the equations defining r and w and for the resource constraint.

 parameters rho delta gamma alpha lambda g;
 trend_var(growth_factor=1+g) G;
// the trend of K is wrong:
 var(deflator=G) C w;
 var L r A K;
// Here is the correct specification:
// var(deflator=G) C w K;
// var L r A;
 varexo e;


 alpha = 0.33;
 delta = 0.1;
 rho = 0.03;
 lambda = 0.97;
 gamma = 0;
 g = 0.015;

 model;
 1/C = 1/(1+rho)*(1/C(+1))*(r(+1)+1-delta);
 L^gamma = w/C;
 r = alpha*A*K(-1)^(alpha-1)*(G*L)^(1-alpha);
 w = (1-alpha)*A*K(-1)^alpha*(G*L)^(-alpha);
 K+C = K(-1)*(1-delta)+A*K(-1)^alpha*(G*L)^(1-alpha);
 log(A) = lambda*log(A(-1))+e;
 end;

 steady_state_model;
 A = 1;
 r = (1+g)*(1+rho)+delta-1;
 K_L = (1+g)*(r/(alpha*A))^(1/(alpha-1));
 w = (1-alpha)*A*(K_L/(1+g))^alpha;
 L = (-((delta+g)/(1+g))*K_L/w+A*(K_L/((1+g)*w^(1/alpha)))^alpha)
     ^(-1/(1+gamma));
 K = K_L*L;
 C = (1-delta)*K/(1+g)+(K_L/(1+g))^alpha*L-K;
 end;

 shocks;
 var e; stderr 0.01;
 end;

write_latex_dynamic_model;

 steady;
 check;

 stoch_simul(order=1);