From 2f9350b164137179abe954133c255e49b4fd91bc Mon Sep 17 00:00:00 2001
From: Houtan Bastani <houtan@dynare.org>
Date: Thu, 15 Feb 2018 12:40:17 +0100
Subject: [PATCH] preprocessor submodule: build system
---
Makefile.am | 98 ++---------------
configure.ac | 110 +++++++++++++++++++
license.txt | 5 +
m4/ax_boost_base.m4 | 260 ++++++++++++++++++++++++++++++++++++++++++++
m4/ax_prog_ln_s.m4 | 27 +++++
src/Makefile.am | 84 ++++++++++++++
6 files changed, 493 insertions(+), 91 deletions(-)
create mode 100755 configure.ac
create mode 100644 m4/ax_boost_base.m4
create mode 100644 m4/ax_prog_ln_s.m4
create mode 100644 src/Makefile.am
diff --git a/Makefile.am b/Makefile.am
index 5a8ac507..c6125521 100644
--- a/Makefile.am
+++ b/Makefile.am
@@ -1,95 +1,11 @@
-SUBDIRS = macro
+SUBDIRS = src
-BUILT_SOURCES = DynareBison.hh stack.hh position.hh location.hh DynareBison.cc DynareFlex.cc FlexLexer.h
+ACLOCAL_AMFLAGS = -I m4
-matlabdir = $(pkglibdir)/matlab
+EXTRA_DIST = \
+ license.txt \
+ COPYING
-matlab_PROGRAMS = dynare_m
+dist-hook:
+ rm -rf `find $(distdir) -name '.git*'`
-# We don't put BUILT_SOURCES in dynare_m_SOURCES, otherwise DynareBison.o and DynareFlex.o will be linked two times (Automake translates DynareFlex.ll and DynareBison.yy into their respective .o); so BUILT_SOURCES is in EXTRA_DIST
-dynare_m_SOURCES = \
- DynareFlex.ll \
- DynareBison.yy \
- ComputingTasks.cc \
- ComputingTasks.hh \
- ModelTree.cc \
- ModelTree.hh \
- StaticModel.cc \
- StaticModel.hh \
- DynamicModel.cc \
- DynamicModel.hh \
- NumericalConstants.cc \
- NumericalConstants.hh \
- NumericalInitialization.cc \
- NumericalInitialization.hh \
- Shocks.cc \
- Shocks.hh \
- SigmaeInitialization.cc \
- SigmaeInitialization.hh \
- SymbolTable.cc \
- SymbolTable.hh \
- SymbolList.cc \
- SymbolList.hh \
- ParsingDriver.cc \
- ParsingDriver.hh \
- DataTree.cc \
- DataTree.hh \
- ModFile.cc \
- ModFile.hh \
- ConfigFile.cc \
- ConfigFile.hh \
- Statement.cc \
- Statement.hh \
- ExprNode.cc \
- ExprNode.hh \
- MinimumFeedbackSet.cc \
- MinimumFeedbackSet.hh \
- DynareMain.cc \
- DynareMain1.cc \
- DynareMain2.cc \
- CodeInterpreter.hh \
- ExternalFunctionsTable.cc \
- ExternalFunctionsTable.hh \
- SteadyStateModel.hh \
- SteadyStateModel.cc \
- WarningConsolidation.hh \
- WarningConsolidation.cc \
- ExtendedPreprocessorTypes.hh
-
-
-# The -I. is for <FlexLexer.h>
-dynare_m_CPPFLAGS = $(BOOST_CPPFLAGS) -I.
-dynare_m_LDFLAGS = $(BOOST_LDFLAGS)
-dynare_m_LDADD = macro/libmacro.a
-
-DynareFlex.cc FlexLexer.h: DynareFlex.ll
- $(LEX) -o DynareFlex.cc DynareFlex.ll
- cp $(LEXINC)/FlexLexer.h . || test -f ./FlexLexer.h
-
-DynareBison.cc DynareBison.hh location.hh stack.hh position.hh: DynareBison.yy
- $(YACC) -o DynareBison.cc DynareBison.yy
-
-all-local: $(PROGRAMS)
- if [ -z "`file $(PROGRAMS) | grep x86.64`" ]; then \
- ARCH="32"; \
- else \
- ARCH="64"; \
- fi; \
- mkdir -p ../matlab/preprocessor$$ARCH ; \
- cd ../matlab/preprocessor$$ARCH && $(LN_S) -f $(abs_srcdir)/$(PROGRAMS) $(PROGRAMS) ; \
- mkdir -p ../../julia/preprocessor$$ARCH ; \
- cd ../../julia/preprocessor$$ARCH && $(LN_S) -f $(abs_srcdir)/$(PROGRAMS) $(PROGRAMS)
-
-if HAVE_DOXYGEN
-html-local:
- $(DOXYGEN)
-endif
-
-clean-local:
- rm -rf ../matlab/preprocessor* ../julia/preprocessor*
- rm -rf doc/html/
-
-EXTRA_DIST = $(BUILT_SOURCES) Doxyfile
-
-install-exec-local:
- $(MKDIR_P) $(DESTDIR)$(pkglibdir)/matlab
diff --git a/configure.ac b/configure.ac
new file mode 100755
index 00000000..bb2e3551
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,110 @@
+dnl Process this file with autoconf to produce a configure script.
+
+dnl Copyright (C) 2009-2018 Dynare Team
+dnl
+dnl This file is part of Dynare.
+dnl
+dnl Dynare is free software: you can redistribute it and/or modify
+dnl it under the terms of the GNU General Public License as published by
+dnl the Free Software Foundation, either version 3 of the License, or
+dnl (at your option) any later version.
+dnl
+dnl Dynare is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+dnl GNU General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU General Public License
+dnl along with Dynare. If not, see <http://www.gnu.org/licenses/>.
+
+AC_PREREQ([2.62])
+AC_INIT([dynare-preprocessor], [1.0])
+AC_CONFIG_SRCDIR([src/DynareMain.cc])
+AM_INIT_AUTOMAKE([1.11 -Wall -Wno-portability foreign no-dist-gzip dist-xz tar-pax])
+
+AC_PROG_CC
+AC_PROG_CXX
+
+AC_CANONICAL_HOST
+case ${host_os} in
+ *mingw32*)
+ # On mingw32, we don't want dynamic libgcc
+ # Note that static-libstdc++ is only supported since GCC 4.5 (but generates no error on older versions)
+ LDFLAGS="$LDFLAGS -static-libgcc -static-libstdc++ -static-libgfortran"
+ have_windows="yes"
+ ;;
+ *cygwin*)
+ AC_MSG_WARN([You are compiling for the Cygwin target. This means that the preprocessor will])
+ AC_MSG_WARN([not run from MATLAB unless you add the Cygwin DLL to the path.])
+ AC_MSG_WARN([This is probably not what you want. Consider using a MinGW cross-compiler.])
+ have_windows="yes"
+ ;;
+esac
+
+# Use C++ for testing headers
+AC_LANG([C++])
+
+CXXFLAGS="$CXXFLAGS -Wall -Wno-parentheses"
+
+# If default 'ar' is not available, try to find one with a host prefix (see ticket #145)
+AC_CHECK_PROGS([AR], [ar ${host_alias}-ar])
+
+AC_PROG_RANLIB
+AM_PROG_AR
+
+AX_PROG_LN_S
+
+AC_PROG_MKDIR_P
+
+AM_PROG_LEX
+# Hack to get lex include dir, ticket #575
+AC_PATH_PROG([LEXPATH], [$LEX])
+AC_SUBST([LEXINC], [`eval "echo $LEXPATH | sed 's|\(.*\)$LEX$|\1../include|'"`])
+
+AC_CHECK_PROG([YACC], [bison], [bison])
+if test "x$YACC" = "x"; then
+ unset YACC # AM_MISSING_PROG needs an unset variable: an empty variable won't do
+ AM_MISSING_PROG([YACC], [bison])
+fi
+
+# We need 1.36 because of unordered_{set,hash} used by Dynare++
+AX_BOOST_BASE([1.36], [], [AC_MSG_ERROR([Can't find Boost >= 1.36])])
+
+CPPFLAGS_SAVED="$CPPFLAGS"
+CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
+AC_CHECK_HEADERS([boost/graph/adjacency_list.hpp], [], [AC_MSG_ERROR([Can't find Boost Graph Library])])
+AC_CHECK_HEADERS([boost/algorithm/string/trim.hpp], [], [AC_MSG_ERROR([Can't find Boost String Library])])
+AC_CHECK_HEADERS([boost/algorithm/string/split.hpp], [], [AC_MSG_ERROR([Can't find Boost String Library])])
+AC_CHECK_HEADERS([boost/lexical_cast.hpp], [], [AC_MSG_ERROR([Can't find Boost Lexical Cast Header])])
+CPPFLAGS="$CPPFLAGS_SAVED"
+
+# Don't use deprecated hash structures
+AC_DEFINE([BOOST_NO_HASH], [], [Don't use deprecated STL hash structures])
+
+AC_CHECK_PROG([DOXYGEN], [doxygen], [doxygen])
+AM_CONDITIONAL([HAVE_DOXYGEN], [test "x$DOXYGEN" != "x"])
+
+AC_CONFIG_FILES([Makefile
+ src/Makefile
+ src/macro/Makefile
+])
+
+if test "x$DOXYGEN" != "x"; then
+ BUILD_DYNARE_PREPROC_DOC="yes"
+else
+ BUILD_DYNARE_PREPROC_DOC="no (missing doxygen)"
+fi
+
+AC_MSG_NOTICE([
+
+The Dynare Preprocessor is now configured to build...
+
+Binaries (with "make")
+ Dynare preprocessor: yes
+
+HTML documentation (with "make html"):
+ Dynare preprocessor developer doc: $BUILD_DYNARE_PREPROC_DOC
+
+])
+
+AC_OUTPUT
diff --git a/license.txt b/license.txt
index 2cbbcb68..bfa79484 100644
--- a/license.txt
+++ b/license.txt
@@ -16,6 +16,11 @@ Files: *
Copyright: 1996-2018 Dynare Team
License: GPL-3+
+Files: m4/ax_boost_base.m4
+Copyright: 2008 Thomas Porschberg <thomas@randspringer.de>
+ 2009 Peter Adolphs
+License: permissive-autoconf
+
License: GPL-3+
Dynare is free software: you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
diff --git a/m4/ax_boost_base.m4 b/m4/ax_boost_base.m4
new file mode 100644
index 00000000..57d14fe4
--- /dev/null
+++ b/m4/ax_boost_base.m4
@@ -0,0 +1,260 @@
+# ===========================================================================
+# http://www.gnu.org/software/autoconf-archive/ax_boost_base.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+# AX_BOOST_BASE([MINIMUM-VERSION], [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
+#
+# DESCRIPTION
+#
+# Test for the Boost C++ libraries of a particular version (or newer)
+#
+# If no path to the installed boost library is given the macro searchs
+# under /usr, /usr/local, /opt and /opt/local and evaluates the
+# $BOOST_ROOT environment variable. Further documentation is available at
+# <http://randspringer.de/boost/index.html>.
+#
+# This macro calls:
+#
+# AC_SUBST(BOOST_CPPFLAGS) / AC_SUBST(BOOST_LDFLAGS)
+#
+# And sets:
+#
+# HAVE_BOOST
+#
+# LICENSE
+#
+# Copyright (c) 2008 Thomas Porschberg <thomas@randspringer.de>
+# Copyright (c) 2009 Peter Adolphs
+#
+# Copying and distribution of this file, with or without modification, are
+# permitted in any medium without royalty provided the copyright notice
+# and this notice are preserved. This file is offered as-is, without any
+# warranty.
+
+#serial 21
+
+AC_DEFUN([AX_BOOST_BASE],
+[
+AC_ARG_WITH([boost],
+ [AS_HELP_STRING([--with-boost@<:@=ARG@:>@],
+ [use Boost library from a standard location (ARG=yes),
+ from the specified location (ARG=<path>),
+ or disable it (ARG=no)
+ @<:@ARG=yes@:>@ ])],
+ [
+ if test "$withval" = "no"; then
+ want_boost="no"
+ elif test "$withval" = "yes"; then
+ want_boost="yes"
+ ac_boost_path=""
+ else
+ want_boost="yes"
+ ac_boost_path="$withval"
+ fi
+ ],
+ [want_boost="yes"])
+
+
+AC_ARG_WITH([boost-libdir],
+ AS_HELP_STRING([--with-boost-libdir=LIB_DIR],
+ [Force given directory for boost libraries. Note that this will override library path detection, so use this parameter only if default library detection fails and you know exactly where your boost libraries are located.]),
+ [
+ if test -d "$withval"
+ then
+ ac_boost_lib_path="$withval"
+ else
+ AC_MSG_ERROR(--with-boost-libdir expected directory name)
+ fi
+ ],
+ [ac_boost_lib_path=""]
+)
+
+if test "x$want_boost" = "xyes"; then
+ boost_lib_version_req=ifelse([$1], ,1.20.0,$1)
+ boost_lib_version_req_shorten=`expr $boost_lib_version_req : '\([[0-9]]*\.[[0-9]]*\)'`
+ boost_lib_version_req_major=`expr $boost_lib_version_req : '\([[0-9]]*\)'`
+ boost_lib_version_req_minor=`expr $boost_lib_version_req : '[[0-9]]*\.\([[0-9]]*\)'`
+ boost_lib_version_req_sub_minor=`expr $boost_lib_version_req : '[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\)'`
+ if test "x$boost_lib_version_req_sub_minor" = "x" ; then
+ boost_lib_version_req_sub_minor="0"
+ fi
+ WANT_BOOST_VERSION=`expr $boost_lib_version_req_major \* 100000 \+ $boost_lib_version_req_minor \* 100 \+ $boost_lib_version_req_sub_minor`
+ AC_MSG_CHECKING(for boostlib >= $boost_lib_version_req)
+ succeeded=no
+
+ dnl On 64-bit systems check for system libraries in both lib64 and lib.
+ dnl The former is specified by FHS, but e.g. Debian does not adhere to
+ dnl this (as it rises problems for generic multi-arch support).
+ dnl The last entry in the list is chosen by default when no libraries
+ dnl are found, e.g. when only header-only libraries are installed!
+ libsubdirs="lib"
+ ax_arch=`uname -m`
+ case $ax_arch in
+ x86_64|ppc64|s390x|sparc64|aarch64)
+ libsubdirs="lib64 lib lib64"
+ ;;
+ esac
+
+ dnl first we check the system location for boost libraries
+ dnl this location ist chosen if boost libraries are installed with the --layout=system option
+ dnl or if you install boost with RPM
+ if test "$ac_boost_path" != ""; then
+ BOOST_CPPFLAGS="-I$ac_boost_path/include"
+ for ac_boost_path_tmp in $libsubdirs; do
+ if test -d "$ac_boost_path"/"$ac_boost_path_tmp" ; then
+ BOOST_LDFLAGS="-L$ac_boost_path/$ac_boost_path_tmp"
+ break
+ fi
+ done
+ elif test "$cross_compiling" != yes; then
+ for ac_boost_path_tmp in /usr /usr/local /opt /opt/local ; do
+ if test -d "$ac_boost_path_tmp/include/boost" && test -r "$ac_boost_path_tmp/include/boost"; then
+ for libsubdir in $libsubdirs ; do
+ if ls "$ac_boost_path_tmp/$libsubdir/libboost_"* >/dev/null 2>&1 ; then break; fi
+ done
+ BOOST_LDFLAGS="-L$ac_boost_path_tmp/$libsubdir"
+ BOOST_CPPFLAGS="-I$ac_boost_path_tmp/include"
+ break;
+ fi
+ done
+ fi
+
+ dnl overwrite ld flags if we have required special directory with
+ dnl --with-boost-libdir parameter
+ if test "$ac_boost_lib_path" != ""; then
+ BOOST_LDFLAGS="-L$ac_boost_lib_path"
+ fi
+
+ CPPFLAGS_SAVED="$CPPFLAGS"
+ CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
+ export CPPFLAGS
+
+ LDFLAGS_SAVED="$LDFLAGS"
+ LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
+ export LDFLAGS
+
+ AC_REQUIRE([AC_PROG_CXX])
+ AC_LANG_PUSH(C++)
+ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+ @%:@include <boost/version.hpp>
+ ]], [[
+ #if BOOST_VERSION >= $WANT_BOOST_VERSION
+ // Everything is okay
+ #else
+ # error Boost version is too old
+ #endif
+ ]])],[
+ AC_MSG_RESULT(yes)
+ succeeded=yes
+ found_system=yes
+ ],[
+ ])
+ AC_LANG_POP([C++])
+
+
+
+ dnl if we found no boost with system layout we search for boost libraries
+ dnl built and installed without the --layout=system option or for a staged(not installed) version
+ if test "x$succeeded" != "xyes"; then
+ _version=0
+ if test "$ac_boost_path" != ""; then
+ if test -d "$ac_boost_path" && test -r "$ac_boost_path"; then
+ for i in `ls -d $ac_boost_path/include/boost-* 2>/dev/null`; do
+ _version_tmp=`echo $i | sed "s#$ac_boost_path##" | sed 's/\/include\/boost-//' | sed 's/_/./'`
+ V_CHECK=`expr $_version_tmp \> $_version`
+ if test "$V_CHECK" = "1" ; then
+ _version=$_version_tmp
+ fi
+ VERSION_UNDERSCORE=`echo $_version | sed 's/\./_/'`
+ BOOST_CPPFLAGS="-I$ac_boost_path/include/boost-$VERSION_UNDERSCORE"
+ done
+ fi
+ else
+ if test "$cross_compiling" != yes; then
+ for ac_boost_path in /usr /usr/local /opt /opt/local ; do
+ if test -d "$ac_boost_path" && test -r "$ac_boost_path"; then
+ for i in `ls -d $ac_boost_path/include/boost-* 2>/dev/null`; do
+ _version_tmp=`echo $i | sed "s#$ac_boost_path##" | sed 's/\/include\/boost-//' | sed 's/_/./'`
+ V_CHECK=`expr $_version_tmp \> $_version`
+ if test "$V_CHECK" = "1" ; then
+ _version=$_version_tmp
+ best_path=$ac_boost_path
+ fi
+ done
+ fi
+ done
+
+ VERSION_UNDERSCORE=`echo $_version | sed 's/\./_/'`
+ BOOST_CPPFLAGS="-I$best_path/include/boost-$VERSION_UNDERSCORE"
+ if test "$ac_boost_lib_path" = ""; then
+ for libsubdir in $libsubdirs ; do
+ if ls "$best_path/$libsubdir/libboost_"* >/dev/null 2>&1 ; then break; fi
+ done
+ BOOST_LDFLAGS="-L$best_path/$libsubdir"
+ fi
+ fi
+
+ if test "x$BOOST_ROOT" != "x"; then
+ for libsubdir in $libsubdirs ; do
+ if ls "$BOOST_ROOT/stage/$libsubdir/libboost_"* >/dev/null 2>&1 ; then break; fi
+ done
+ if test -d "$BOOST_ROOT" && test -r "$BOOST_ROOT" && test -d "$BOOST_ROOT/stage/$libsubdir" && test -r "$BOOST_ROOT/stage/$libsubdir"; then
+ version_dir=`expr //$BOOST_ROOT : '.*/\(.*\)'`
+ stage_version=`echo $version_dir | sed 's/boost_//' | sed 's/_/./g'`
+ stage_version_shorten=`expr $stage_version : '\([[0-9]]*\.[[0-9]]*\)'`
+ V_CHECK=`expr $stage_version_shorten \>\= $_version`
+ if test "$V_CHECK" = "1" -a "$ac_boost_lib_path" = "" ; then
+ AC_MSG_NOTICE(We will use a staged boost library from $BOOST_ROOT)
+ BOOST_CPPFLAGS="-I$BOOST_ROOT"
+ BOOST_LDFLAGS="-L$BOOST_ROOT/stage/$libsubdir"
+ fi
+ fi
+ fi
+ fi
+
+ CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
+ export CPPFLAGS
+ LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
+ export LDFLAGS
+
+ AC_LANG_PUSH(C++)
+ AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+ @%:@include <boost/version.hpp>
+ ]], [[
+ #if BOOST_VERSION >= $WANT_BOOST_VERSION
+ // Everything is okay
+ #else
+ # error Boost version is too old
+ #endif
+ ]])],[
+ AC_MSG_RESULT(yes)
+ succeeded=yes
+ found_system=yes
+ ],[
+ ])
+ AC_LANG_POP([C++])
+ fi
+
+ if test "$succeeded" != "yes" ; then
+ if test "$_version" = "0" ; then
+ AC_MSG_NOTICE([[We could not detect the boost libraries (version $boost_lib_version_req_shorten or higher). If you have a staged boost library (still not installed) please specify \$BOOST_ROOT in your environment and do not give a PATH to --with-boost option. If you are sure you have boost installed, then check your version number looking in <boost/version.hpp>. See http://randspringer.de/boost for more documentation.]])
+ else
+ AC_MSG_NOTICE([Your boost libraries seems to old (version $_version).])
+ fi
+ # execute ACTION-IF-NOT-FOUND (if present):
+ ifelse([$3], , :, [$3])
+ else
+ AC_SUBST(BOOST_CPPFLAGS)
+ AC_SUBST(BOOST_LDFLAGS)
+ AC_DEFINE(HAVE_BOOST,,[define if the Boost library is available])
+ # execute ACTION-IF-FOUND (if present):
+ ifelse([$2], , :, [$2])
+ fi
+
+ CPPFLAGS="$CPPFLAGS_SAVED"
+ LDFLAGS="$LDFLAGS_SAVED"
+fi
+
+])
diff --git a/m4/ax_prog_ln_s.m4 b/m4/ax_prog_ln_s.m4
new file mode 100644
index 00000000..d9477064
--- /dev/null
+++ b/m4/ax_prog_ln_s.m4
@@ -0,0 +1,27 @@
+dnl Copyright (C) 2009-2010 Dynare Team
+dnl
+dnl This file is part of Dynare.
+dnl
+dnl Dynare is free software: you can redistribute it and/or modify
+dnl it under the terms of the GNU General Public License as published by
+dnl the Free Software Foundation, either version 3 of the License, or
+dnl (at your option) any later version.
+dnl
+dnl Dynare is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+dnl GNU General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU General Public License
+dnl along with Dynare. If not, see <http://www.gnu.org/licenses/>.
+
+AC_DEFUN([AX_PROG_LN_S],
+[
+AC_REQUIRE([AC_CANONICAL_HOST])
+AC_REQUIRE([AC_PROG_LN_S])
+case ${host_os} in
+ *cygwin*|*mingw32*)
+ LN_S="cp -p" # Symbolic links are not understood by MATLAB under Windows
+ ;;
+esac
+])
diff --git a/src/Makefile.am b/src/Makefile.am
new file mode 100644
index 00000000..080c5984
--- /dev/null
+++ b/src/Makefile.am
@@ -0,0 +1,84 @@
+SUBDIRS = macro
+
+BUILT_SOURCES = DynareBison.hh stack.hh position.hh location.hh DynareBison.cc DynareFlex.cc FlexLexer.h
+
+bin_PROGRAMS = dynare_m
+
+# We don't put BUILT_SOURCES in dynare_m_SOURCES, otherwise DynareBison.o and DynareFlex.o will be linked two times (Automake translates DynareFlex.ll and DynareBison.yy into their respective .o); so BUILT_SOURCES is in EXTRA_DIST
+dynare_m_SOURCES = \
+ DynareFlex.ll \
+ DynareBison.yy \
+ ComputingTasks.cc \
+ ComputingTasks.hh \
+ ModelTree.cc \
+ ModelTree.hh \
+ StaticModel.cc \
+ StaticModel.hh \
+ DynamicModel.cc \
+ DynamicModel.hh \
+ NumericalConstants.cc \
+ NumericalConstants.hh \
+ NumericalInitialization.cc \
+ NumericalInitialization.hh \
+ Shocks.cc \
+ Shocks.hh \
+ SigmaeInitialization.cc \
+ SigmaeInitialization.hh \
+ SymbolTable.cc \
+ SymbolTable.hh \
+ SymbolList.cc \
+ SymbolList.hh \
+ ParsingDriver.cc \
+ ParsingDriver.hh \
+ DataTree.cc \
+ DataTree.hh \
+ ModFile.cc \
+ ModFile.hh \
+ ConfigFile.cc \
+ ConfigFile.hh \
+ Statement.cc \
+ Statement.hh \
+ ExprNode.cc \
+ ExprNode.hh \
+ MinimumFeedbackSet.cc \
+ MinimumFeedbackSet.hh \
+ DynareMain.cc \
+ DynareMain1.cc \
+ DynareMain2.cc \
+ CodeInterpreter.hh \
+ ExternalFunctionsTable.cc \
+ ExternalFunctionsTable.hh \
+ SteadyStateModel.hh \
+ SteadyStateModel.cc \
+ WarningConsolidation.hh \
+ WarningConsolidation.cc \
+ ExtendedPreprocessorTypes.hh
+
+
+ACLOCAL_AMFLAGS = -I m4
+
+EXTRA_DIST = \
+ Doxyfile \
+ $(BUILT_SOURCES)
+
+# The -I. is for <FlexLexer.h>
+dynare_m_CPPFLAGS = $(BOOST_CPPFLAGS) -I.
+dynare_m_LDFLAGS = $(BOOST_LDFLAGS)
+dynare_m_LDADD = macro/libmacro.a
+
+DynareFlex.cc FlexLexer.h: DynareFlex.ll
+ $(LEX) -o DynareFlex.cc DynareFlex.ll
+ cp $(LEXINC)/FlexLexer.h . || test -f ./FlexLexer.h
+
+DynareBison.cc DynareBison.hh location.hh stack.hh position.hh: DynareBison.yy
+ $(YACC) -o DynareBison.cc DynareBison.yy
+
+all-local: $(PROGRAMS)
+
+if HAVE_DOXYGEN
+html-local:
+ $(DOXYGEN)
+endif
+
+clean-local:
+ rm -rf doc/html/
--
GitLab