From 908d5bc38611f99198f11378bc2d70905ffbdd23 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?St=C3=A9phane=20Adjemian=28Charybdis=29?=
<stephane.adjemian@univ-lemans.fr>
Date: Wed, 11 Jul 2018 10:12:55 +0200
Subject: [PATCH] Added two examples.
---
examples/10/clean | 7 +++
examples/10/example.mod | 96 +++++++++++++++++++++++++++++++++++++++++
examples/11/clean | 6 +++
examples/11/example.mod | 57 ++++++++++++++++++++++++
4 files changed, 166 insertions(+)
create mode 100755 examples/10/clean
create mode 100644 examples/10/example.mod
create mode 100755 examples/11/clean
create mode 100644 examples/11/example.mod
diff --git a/examples/10/clean b/examples/10/clean
new file mode 100755
index 0000000000..68ebf18414
--- /dev/null
+++ b/examples/10/clean
@@ -0,0 +1,7 @@
+#!/bin/sh
+
+rm -rf example
+rm -f example*.json
+rm -f example*.mat
+rm -f example.log
+rm -f *.m
diff --git a/examples/10/example.mod b/examples/10/example.mod
new file mode 100644
index 0000000000..0212b1b0d2
--- /dev/null
+++ b/examples/10/example.mod
@@ -0,0 +1,96 @@
+// --+ options: json=compute, stochastic +--
+
+var x1 x2 x1bar x2bar z y;
+
+varexo ex1 ex2 ex1bar ex2bar ez ey;
+
+parameters
+ rho_1 rho_2
+ a_x1_0 a_x1_1 a_x1_2 a_x1_x2_1 a_x1_x2_2
+ a_x2_0 a_x2_1 a_x2_2 a_x2_x1_1 a_x2_x1_2
+ e_c_m c_z_1 c_z_2 gamma beta ;
+
+rho_1 = .9;
+rho_2 = -.2;
+
+a_x1_0 = -.9;
+a_x1_1 = .4;
+a_x1_2 = .3;
+a_x1_x2_1 = .1;
+a_x1_x2_2 = .2;
+
+
+a_x2_0 = -.9;
+a_x2_1 = .2;
+a_x2_2 = -.1;
+a_x2_x1_1 = -.1;
+a_x2_x1_2 = .2;
+
+beta = .2;
+e_c_m = .5;
+c_z_1 = .2;
+c_z_2 = -.1;
+
+var_model(model_name=toto, eqtags=['eq:x1', 'eq:x2', 'eq:x1bar', 'eq:x2bar']);
+
+pac_model(var_model_name=toto, discount=beta, model_name=pacman, undiff('eq:x1', 1), undiff('eq:x2', 1));
+
+model;
+
+[name='eq:y']
+y = rho_1*y(-1) + rho_2*y(-2) + ey;
+
+[name='eq:x1', data_type='nonstationary']
+diff(x1) = a_x1_0*(x1(-1)-x1bar(-1)) + a_x1_1*diff(x1(-1)) + a_x1_2*diff(x1(-2)) + a_x1_x2_1*diff(x2(-1)) + a_x1_x2_2*diff(x2(-2)) + ex1;
+
+[name='eq:x2', data_type='nonstationary']
+diff(x2) = a_x2_0*(x2(-1)-x2bar(-1)) + a_x2_1*diff(x1(-1)) + a_x2_2*diff(x1(-2)) + a_x2_x1_1*diff(x2(-1)) + a_x2_x1_2*diff(x2(-2)) + ex2;
+
+[name='eq:x1bar', data_type='nonstationary']
+x1bar = x1bar(-1) + ex1bar;
+
+[name='eq:x2bar', data_type='nonstationary']
+x2bar = x2bar(-1) + ex2bar;
+
+[name='zpac']
+diff(z) = e_c_m*(x1(-1)-z(-1)) + c_z_1*diff(z(-1)) + c_z_2*diff(z(-2)) + pac_expectation(pacman) + ez;
+
+end;
+
+shocks;
+ var ex1 = 1.0;
+ var ex2 = 1.0;
+ var ex1bar = 1.0;
+ var ex2bar = 1.0;
+ var ez = 1.0;
+ var ey = 0.1;
+end;
+
+// Build the companion matrix of the VAR model (toto).
+get_companion_matrix('toto', 'pacman');
+
+// Update the parameters of the PAC expectation model (h0 and h1 vectors).
+pac.update.expectation('pacman');
+
+// Set initial conditions to zero. Please use more sensible values if any...
+initialconditions = dseries(zeros(10, M_.endo_nbr+M_.exo_nbr), 2000Q1, vertcat(M_.endo_names,M_.exo_names));
+
+// Simulate the model for 500 periods
+TrueData = simul_backward_model(initialconditions, 500);
+
+//[pnames, enames, xnames, pid, eid, xid] = get_variables_and_parameters_in_equation('zpac', M_)
+
+// Define a structure describing the parameters to be estimated (with initial conditions).
+eparams.e_c_m = .9;
+eparams.c_z_1 = .5;
+eparams.c_z_2 = .2;
+
+//Â Define the dataset used for estimation
+edata = TrueData;
+edata.ez = dseries(NaN(TrueData.nobs, 1), 200Q1, 'ez');
+
+pac.estimate('zpac', eparams, edata, 2005Q1:2120Q1);
+
+disp(sprintf('Estimate of e_c_m: %f', M_.params(strmatch('e_c_m', M_.param_names, 'exact'))))
+disp(sprintf('Estimate of c_z_1: %f', M_.params(strmatch('c_z_1', M_.param_names, 'exact'))))
+disp(sprintf('Estimate of c_z_2: %f', M_.params(strmatch('c_z_2', M_.param_names, 'exact'))))
diff --git a/examples/11/clean b/examples/11/clean
new file mode 100755
index 0000000000..be0d5e00cd
--- /dev/null
+++ b/examples/11/clean
@@ -0,0 +1,6 @@
+#!/bin/sh
+
+rm -rf example
+rm -rf +example
+rm -f example*.mat
+rm -f example.log
\ No newline at end of file
diff --git a/examples/11/example.mod b/examples/11/example.mod
new file mode 100644
index 0000000000..31c1512a24
--- /dev/null
+++ b/examples/11/example.mod
@@ -0,0 +1,57 @@
+// --+ options: json=compute, stochastic +--
+
+var y x z;
+
+varexo ex ey ez;
+
+parameters a_y_1 a_y_2 b_y_1 b_y_2 b_x_1 b_x_2 ; // VAR parameters
+
+parameters g beta e_c_m c_z_1 c_z_2; // PAC equation parameters
+
+a_y_1 = .2;
+a_y_2 = .3;
+b_y_1 = .1;
+b_y_2 = .4;
+b_x_1 = -.1;
+b_x_2 = -.2;
+
+beta = .9;
+e_c_m = .1;
+c_z_1 = .7;
+c_z_2 = -.3;
+
+g = .1;
+
+var_model(model_name=toto, eqtags=['eq:x', 'eq:y']);
+
+pac_model(var_model_name=toto, discount=beta, model_name=pacman, growth=g);
+
+model;
+
+[name='eq:y']
+y = a_y_1*y(-1) + a_y_2*diff(x(-1)) + b_y_1*y(-2) + b_y_2*diff(x(-2)) + ey ;
+
+[name='eq:x', data_type='nonstationary']
+diff(x) = b_x_1*y(-2) + b_x_2*diff(x(-1)) + g*(1-b_x_2) + ex ;
+
+[name='eq:pac']
+diff(z) = e_c_m*(x(-1)-z(-1)) + c_z_1*diff(z(-1)) + c_z_2*diff(z(-2)) + pac_expectation(pacman) + ez;
+
+end;
+
+shocks;
+ var ex = 1.0;
+ var ey = 1.0;
+ var ez = 1.0;
+end;
+
+get_companion_matrix('toto', 'pacman');
+
+// Update the parameters of the PAC expectation model (h0 and h1 vectors).
+pac.update.expectation('pacman');
+
+// Set initial conditions to zero. Please use more sensible values if any...
+initialconditions = dseries(zeros(10, M_.endo_nbr+M_.exo_nbr), 2000Q1, vertcat(M_.endo_names,M_.exo_names));
+
+// Simulate the model for 500 periods
+TrueData = simul_backward_model(initialconditions, 500);
\ No newline at end of file
--
GitLab